Mobiclic 47/MOBICLIC 47.ISO/mac/DATA/COMMUNS/MOBICLIC_MENUS.CST/00003_Script_gestion de la navigation

Text File | 2002-09-19 | 6KB | 220 lines

-- gestion de la navigation

global chemin,pathAide,menuMsg,validMBG,validMHD,volumeOn,touchesOn,pisteAideRub,aideRub
global menusActifs, menuOuvert,  gFlag_special_EKR
-- chemin    : chemin d'accΦs complet au niveau du sommaire
-- pathAide  : nom complet du film appelant l'aide
-- menuMsg   : nom du message retournΘ par les menus de Mobiclic
-- validMBG  : liste de l'activitΘ des items du menu Θquerre bleue
-- validMHD  : liste de l'activitΘ des items du menu Θquerre verte
-- touchesOn : controle l'activation des raccourcis clavier

-- navigation entre films
on acces
  set n = the paramCount
  if n > 0 then
    initFilm
    nom = chemin
    if n > 1 then
      -- chemin d'accΦs a ΘtΘ envoyΘ sous forme de plusieurs paramΦtres
      repeat with i=1 to n
        if the machineType = 256 then
          nom = nom & param(i) & "\"
        else
          nom = nom & param(i) & ":"
        end if
      end repeat
      delete char(nom.chars.count) of nom
    else
      -- chemin d'accΦs a ΘtΘ envoyΘ sous forme d'un seul paramΦtre
      if offset(":",param(1)) = 0 and offset("\",param(1)) = 0 then
        -- seulement un nom de fichier a ΘtΘ envoyΘ
        nom = param(1)
      else
        -- un chemin d'accΦs a ΘtΘ envoyΘ
        n = param(1)
        nom = nom & nomDos(n)
      end if
    end if
    put "AccΦs au film : " & nom
    nom = nom & ".dir"
    put nom
    go to movie nom
    niveauSon
  end if
end acces

on initFilm
  coupeSon 2,3,4
  menusActifs=1
  menuOuvert = 0
end initFilm

-- retour au sommaire
on sommaire
  quitterAtlas
  coupeSon 2,3,4
  if gFlag_special_EKR <> VOID  then-- permet de gΘrer la commande en interne dans le .dir concernΘ grΓce α la procΘdure locale
    local_sommaire()
  else
    go to movie chemin & "sommaire"
    put "Ouverture du sommaire α " & the time
    niveauSon
  end if
end sommaire
-----------------------------------------
-- accΦs aide gΘnΘrale de Mobiclic
on aideMob
  if gFlag_special_EKR <> VOID  then-- permet de gΘrer la commande en interne dans le .dir concernΘ grΓce α la procΘdure locale
    local_aideMob()
    exit
  end if
  pathAide = the pathName & the movieName
  --  acces("communs","aide")
  go movie "@//COMMUNS/AIDE"
end aideMob
-----------------------------------------
on retourAide
  updateStage
  coupeSon 2,3
  menusActifs=1
  menuOuvert = 0
  case(pathaide) of
    "SOMMAIRE":
      go frame "SOMMAIRE" of movie "SOMMAIRE"
    otherwise:
      go to movie pathAide
  end case
end retourAide


on aideRub
  if aideRub=0 then
    if the movieName contains "LAN" then
      sprite(pisteAideRub).member = member "aideRub"
    end if
    afficherPistes pisteAideRub
    afficherPistes 1+pisteAideRub
    updateStage
    aideRub=1
    menusActifs=0
    volumeOn=1
    menuOuvert = 1
  else
    if the movieName contains "LAN" then
      sprite(pisteAideRub).member = member "pointPourGlisserSur"
    end if
    masquerPistes 1+pisteAideRub,pisteAideRub
    aideRub=0
    menusActifs=1
    volumeOn=0
    menuOuvert = 0
  end if
end
---------------------------------
-- quitter mobiclic
on quitte
  quitterAtlas
  if gFlag_special_EKR <> VOID  then-- permet de gΘrer la commande en interne dans le .dir concernΘ grΓce α la procΘdure locale
    local_quit()
    exit
  end if
  if the optionDown=1 then
    quit
  else
    acces("communs","generic")
  end if
end quitte
---------------------------------
-- gestion de la navigation par flΦches
on keyDown
  if the moviename contains "_MIAW" then
    pass
    exit
  end if
  if touchesOn=1 then
    set k = the keyCode
    if the machineType = 256 then
      nomCh="raccourcisPC"
    else
      nomCh="raccourcis"
    end if
    repeat with i = 1 to member(nomCh).lines.count
      if k = value(member(nomCh).line[i].word[1]) then
        menuMsg = member(nomCh).line[i].word[2]
        -- annulation raccourci clavier selon activation dans le menu
        case menuMsg of
          "dico": -- appui sur le raccourci clavier dictionnaire
            liste=value(member("selectMenus").line[3])
            if liste[3]=0 then
              menuMsg = empty
              exit repeat
            end if
          "infos": -- appui sur le raccourci clavier dictionnaire
            liste=value(member("selectMenus").line[3])
            if liste[4]=0 then
              menuMsg = empty
              exit repeat
            end if
          "debut": -- appui sur la flΦche haut
            liste=value(member("selectMenus").line[2])
            if liste[3]=0 then
              menuMsg = empty
              exit repeat
            end if
          "retour": -- appui sur flΦche gauche
            liste=value(member("selectMenus").line[2])
            if liste[6]=0 then
              menuMsg = empty
              exit repeat
            end if
          "suite": -- appui sur flΦche droite

            liste=value(member("selectMenus").line[2])
            if liste[5]=0 then
              menuMsg = empty
              exit repeat
            end if
          "stop": -- appui sur la barre d'espace (pause)
            liste=value(member("selectMenus").line[2])
            if liste[2]=0 then
              menuMsg = empty
              exit repeat
            end if
          "revoir": -- appui sur la flΦche bas
            liste=value(member("selectMenus").line[2])
            if liste[4]=0 then
              menuMsg = empty
              exit repeat
            end if
          "sommaire": -- appui sur la lettre S
            liste=value(member("selectMenus").line[2])
            if liste[1]=0 then
              menuMsg = empty
              exit repeat
            end if
          "volume": -- appui sur la lettre V
            if field "menuOuvert"<>"0" or volumeOn=1 then
              menuMsg = empty
              exit repeat
            end if
        end case
        if menuMsg <> empty then
          do menuMsg
          menuMsg = empty
        end if
        exit
      end if
    end repeat
  end if
end keyDown

-- activation des raccourcis clvier
on touchesOn
  touchesOn=1
end

-- dΘsactivation des raccourcis clavier
on touchesOff
  touchesOn=0
end